home *** CD-ROM | disk | FTP | other *** search
/ BCI NET / BCI NET Dec 94.iso / archives / programming / languages / brainfuck-2.lha / src / prime.b < prev    next >
Encoding:
Text File  |  1993-06-02  |  4.0 KB  |  222 lines
  1. ===================================================================
  2. ======================== OUTPUT STRING ============================
  3. ===================================================================
  4. >++++++++[<++++++++>-]<++++++++++++++++.[-]
  5. >++++++++++[<++++++++++>-]<++++++++++++++.[-]
  6. >++++++++++[<++++++++++>-]<+++++.[-]
  7. >++++++++++[<++++++++++>-]<+++++++++.[-]
  8. >++++++++++[<++++++++++>-]<+.[-]
  9. >++++++++++[<++++++++++>-]<+++++++++++++++.[-]
  10. >+++++[<+++++>-]<+++++++.[-]
  11. >++++++++++[<++++++++++>-]<+++++++++++++++++.[-]
  12. >++++++++++[<++++++++++>-]<++++++++++++.[-]
  13. >+++++[<+++++>-]<+++++++.[-]
  14. >++++++++++[<++++++++++>-]<++++++++++++++++.[-]
  15. >++++++++++[<++++++++++>-]<+++++++++++.[-]
  16. >+++++++[<+++++++>-]<+++++++++.[-]
  17. >+++++[<+++++>-]<+++++++.[-]
  18.  
  19. ===================================================================
  20. ======================== INPUT NUMBER  ============================
  21. ===================================================================
  22. +                          cont=1
  23. [
  24.  -                         cont=0
  25.  >,
  26.  ======SUB10======
  27.  ----------
  28.  
  29.  [                         not 10
  30.   <+>                      cont=1
  31.   =====SUB38======
  32.   ----------
  33.   ----------
  34.   ----------
  35.   --------
  36.  
  37.   >
  38.   =====MUL10=======
  39.   [>+>+<<-]>>[<<+>>-]<     dup
  40.  
  41.   >>>+++++++++
  42.   [
  43.    <<<
  44.    [>+>+<<-]>>[<<+>>-]<    dup
  45.    [<<+>>-]
  46.    >>-
  47.   ]
  48.   <<<[-]<
  49.   ======RMOVE1======
  50.   <
  51.   [>+<-]
  52.  ]
  53.  <
  54. ]
  55. >>[<<+>>-]<<
  56.  
  57. ===================================================================
  58. ======================= PROCESS NUMBER  ===========================
  59. ===================================================================
  60.  
  61. ==== ==== ==== ====
  62. numd numu teid teiu
  63. ==== ==== ==== ====
  64.  
  65. >+<-
  66. [
  67.  >+
  68.  ======DUP======
  69.  [>+>+<<-]>>[<<+>>-]<
  70.  
  71.  >+<--
  72.  
  73.  >>>>>>>>+<<<<<<<<   isprime=1
  74.  
  75.  [
  76.   >+
  77.  
  78.   <-
  79.  
  80.   =====DUP3=====
  81.   <[>>>+>+<<<<-]>>>>[<<<<+>>>>-]<<<
  82.  
  83.   =====DUP2=====
  84.   >[>>+>+<<<-]>>>[<<<+>>>-]<<< <
  85.  
  86.  
  87.   >>>
  88.  
  89.  
  90.   ====DIVIDES=======
  91.   [>+>+<<-]>>[<<+>>-]<   DUP i=div
  92.   
  93.   <<
  94.   [
  95.     >>>>>+               bool=1
  96.     <<<
  97.     [>+>+<<-]>>[<<+>>-]< DUP
  98.     [>>[-]<<-]           IF i THEN bool=0
  99.     >>
  100.     [                    IF i=0
  101.       <<<<
  102.       [>+>+<<-]>>[<<+>>-]< i=div
  103.       >>>
  104.       -                  bool=0
  105.     ]
  106.     <<<
  107.     -                    DEC i
  108.     <<
  109.     -
  110.   ]
  111.   
  112.   +>>[<<[-]>>-]<<          
  113.   >[-]<                  CLR div
  114.   =====END DIVIDES====
  115.  
  116.  
  117.   [>>>>>>[-]<<<<<<-]     if divides then isprime=0
  118.  
  119.  
  120.   <<
  121.  
  122.   >>[-]>[-]<<<
  123.  ]
  124.  
  125.  >>>>>>>>
  126.  [
  127.   -
  128.   <<<<<<<[-]<<
  129.  
  130.   [>>+>+<<<-]>>>[<<<+>>>-]<<<
  131.  
  132.   >>
  133.  
  134.  
  135.  
  136.  
  137.   ===================================================================
  138.   ======================== OUTPUT NUMBER  ===========================
  139.   ===================================================================
  140.   [>+<-]>
  141.  
  142.   [
  143.    ======DUP======
  144.    [>+>+<<-]>>[<<+>>-]<
  145.   
  146.   
  147.    ======MOD10====
  148.    >+++++++++<
  149.    [
  150.     >>>+<<              bool= 1
  151.     [>+>[-]<<-]         bool= ten==0
  152.     >[<+>-]             ten = tmp
  153.     >[<<++++++++++>>-]  if ten=0 ten=10
  154.     <<-                 dec ten     
  155.     <-                  dec num
  156.    ]
  157.    +++++++++            num=9
  158.    >[<->-]<             dec num by ten
  159.   
  160.    =======RROT======
  161.       [>+<-]
  162.    <  [>+<-]
  163.    <  [>+<-]
  164.    >>>[<<<+>>>-]
  165.    <
  166.   
  167.    =======DIV10========
  168.    >+++++++++<
  169.    [
  170.     >>>+<<                bool= 1
  171.     [>+>[-]<<-]           bool= ten==0
  172.     >[<+>-]               ten = tmp
  173.     >[<<++++++++++>>>+<-] if ten=0 ten=10  inc div
  174.     <<-                   dec ten     
  175.     <-                    dec num
  176.    ]
  177.    >>>>[<<<<+>>>>-]<<<<   copy div to num
  178.    >[-]<                  clear ten
  179.   
  180.    =======INC1=========
  181.    <+>
  182.   ]
  183.   
  184.   <
  185.   [
  186.    =======MOVER=========
  187.    [>+<-]
  188.   
  189.    =======ADD48========
  190.    +++++++[<+++++++>-]<->
  191.   
  192.    =======PUTC=======
  193.    <.[-]>
  194.   
  195.    ======MOVEL2========
  196.    >[<<+>>-]<
  197.   
  198.    <-
  199.   ]
  200.  
  201.   >++++[<++++++++>-]<.[-]
  202.  
  203.   ===================================================================
  204.   =========================== END FOR ===============================
  205.   ===================================================================
  206.  
  207.  
  208.   >>>>>>>
  209.  ]
  210.  <<<<<<<<
  211.  
  212.  
  213.  
  214.  >[-]<
  215.   [-]
  216.  <<-
  217. ]
  218.  
  219. ======LF========
  220.  
  221. ++++++++++.[-]
  222.